#include "colors.inc"
#include "textures.inc"
#declare MG_Sky =
pigment {
    bozo
    turbulence 0.56
    color_map {
	[0.0 rgbt 1.0]
	[0.4 rgbt <0, 0, 1.0, 0.9>]
        [0.5 rgbf <0.5, 0.5, 1.0, 0.8>]
        [0.6 rgbf <1.0, 1.0, 1.0, 0.1>]
        [1.0 rgb 0.5]
    }
}

light_source{ <0,10,10> color White}
light_source{ <-200,-100,300> color White}
difference{
	sphere{<0,200,200>,160 }
	sphere{<0,200,200>,150 }
	texture {MG_Sky scale 7.5}
}
sphere{<0,200,200>,149 texture{Jade scale 7}}
	
#declare Ship1=texture{pigment {rgb <0.9,0.9,0.9>}
	normal{dents 3.5 scale <0.1,0.1,1>}}
#declare Ship2=texture{pigment {rgb <0.8,0.8,1>}
	normal{dents 3.5 scale <0.1,0.1,1>}}
#declare Ship3=texture{pigment {rgb <0.8,0.85,1>}
	normal{dents 3.5 scale <0.15,0.1,0.5>}}
#declare LWing=difference{
        box{<0,-0.1666,0> <5,0.1666,8>}
        plane{z,8 inverse}
        box{<4,-0.1667,-0.001> <5.001,0.1667,1.001>}
        plane{<7,0,4>,5 inverse}
        plane{<7,11,4>,2.7 inverse}
}
#declare RWing=difference{
        box{<0,-0.1666,0> <5,0.1666,8>}
        plane{z,8 inverse}
        box{<4,-0.1667,-0.001> <5.001,0.1667,1.001>}
        plane{<7,0,4>,5 inverse}
        plane{<7,-11,4>,2.7 inverse}
}
#declare Xwinglogo=union{
	cylinder{<0,0,0> <0,0.1,0>,1 texture{Blue_Sky2}}
	difference{
		cylinder{<0,0.09,0> <0,0.13,0>,1 scale<1.2,1,0.8>}
		cylinder{<-0,0,0> <0,0.21,0>,1 scale<1.59,3,0.87> 
			translate<0.75,0,0.1>}
		texture{New_Brass}
		}
	}
#declare Engine=union {
        difference{
                cone{<0,0.5,0>,2.1 <0,3,0>,1 }
                cone{<0,0.3,0>,2.1 <0,2.8,0>,1}
                
                }
        union{
                cone{<0,0.3,0>,2.1 <0,2.8,0>,1}
                cylinder{<0,0.3,0> <0,-5.4,0>,2.3}
                pigment{rgbf <1,1,1,1>}
                hollow
                interior{media{emission rgb<1,0.2,0.4>
                        density{spherical scale <2.5,4,2>}}}
                }
        cylinder{<0,3,0> <0,4,0>,1 }
        cylinder{<0,4,0> <0,5,0>,0.5 }
        cylinder{<0,5,0> <0,6,0>,0.25 }
        box{<-1,6,-1> <1,6.1,1> }
        box{<-1,4,0.9> <1,6,1> }
        cylinder{<0,6.1,0> <0,8,0>,1 texture {Lightening1}}
        box{<-1,8,-1> <1,8.1,1> }
        box{<-1,6,0.9> <1,8,1> }
        cylinder{<0,8,0> <0,9,0>,0.5 }
        cylinder{<0,9,0> <0,10,0>,0.25 }
        cone{<0,10,0>,1 <0,12,0>,0.21 }
        cylinder{<0,12,0> <0,13.5,0>,0.15 texture {Ruby_Glass}
                finish {ambient 1}}              
}
#declare X1Fighter=union{

/* the leading 2 antennae here... */
union{
box {<-1,-0.1666,9.666> <1,0.1666,10> }
cylinder{<-1.1,-0.1666,9.666> <-1.1,-0.1666,11>,0.15 pigment {Red}}
cylinder{<1.1,-0.1666,9.666> <1.1,-0.1666,11>,0.15 pigment {Red}}
translate<0,-0.166,-0.5>
}

/* the "floor" of the ship and its "landing legs" */
box {<-3,-0.5,-5> <3,-0.1666,3> }
box {<-1,-0.5,3> <1,-0.1666,8> }
cylinder {<-2,-1,-4> <-2,-0.5,-4>,0.7 }
cylinder {<2,-1,-4> <2,-0.5,-4>,0.7 }
cylinder {<0,-1,2> <0,-0.5,2>,0.7 }
cylinder {<0,-1,7> <0,-0.5,7>,0.7 }

/* the wings and engines */
object {LWing scale <1,1,1.2> }
object {RWing scale <1,1,1.2> rotate y*180 rotate x*180 }
object {LWing rotate y*270 translate <-3,0,-4> }
object {RWing rotate y*270 translate <-3,0,-4> rotate z*180 }
object {Engine scale <1,1.2,1.1> rotate x*90 translate <2.9,1.55,-10>}
object {Engine scale <1,1.2,1.1> rotate x*90 translate <-2.9,1.55,-10>}

/* the place where a logo will go */
difference{
        box{<-1.5,-0.1666,3> <1.5,1.5,8>}
        plane{<0,1,0.4>,2.5 inverse}
        plane{<9,0,3>,2.5 inverse}
        plane{<-9,0,3>,2.5 inverse}
        
}
box{<-1.6,-0.1666,-5> <1.6,1.7,3> }
difference{
        box{<-0.15,1.7,-7> <0.15,3.7,-2.5> }
        plane{<0,1,1>,-0.5 inverse}
        plane{<0,1,1>,-2.5 }
        
        }
difference{
        box{<-7,3.7,-7> <7,3.9,-4> }
        plane{<0,1.1,0.9>,0 inverse}
        plane{<-1,1.1,0>,5 inverse}
        plane{<1,1.1,0>,5 inverse}
        
        }

union{
difference{
        sphere{<0,1.85,0>,1 scale<1.3,1.2,2.6> }
        sphere{<0,2.1,0>,1 scale<1.1,1.2,2.4>}
         finish {diffuse 0.7 }
}
object{Xwinglogo rotate <-15,0,0> translate <-6,-0.4,-2>}
object{Xwinglogo rotate <-15,0,0> translate <6,-0.4,-2>}
sphere{<0,2.1,0>,1 scale<1.1,1.1,2.35> texture {Vicks_Bottle_Glass}
        finish {phong 1 phong_size 80 ambient rgb <0.2,0.2,0.5>}}
rotate <15,0,0>
translate<0,0,-0.5>
}
}

object {X1Fighter texture{Ship1} 
	rotate <-80,0,5> translate <0,4,25>}
object {X1Fighter texture{Ship2} 
	rotate <-80,0,-15> translate <-20,14,35>}
object {X1Fighter texture{Ship3} 
	rotate <-80,0,15> translate <30,14,55>}
object {X1Fighter texture{Ship2} 
	rotate <-80,0,-15> translate <-20,14,65>}
object {X1Fighter texture{Ship3} 
	rotate <-80,0,15> translate <10,18,75>}
object {X1Fighter texture{Ship1} 
	rotate <-80,0,15> translate <40,28,65>}
sphere {<120,-35,250>,60 texture{Blood_Sky scale 6} finish{ambient 0.8}}
plane{<0,0,1>,400 inverse texture{Starfield} translate <-300,-100,0>}
camera{ location <0,-3,2> look_at<0,0,16> }