// rendered with povray +kff48 +H240 +W320 +A0.2 shareicon-grumpy.pov
#include "colors.inc"
#include "textures.inc"
#include "metals.inc"

light_source{ <-10,10,-11> color White}
light_source{
    <10,10,-11>
    color White
    spotlight
    radius 15
    falloff 20
    tightness 10
    point_at <0,0,0>
}
camera{
    location <-4,0,-6> rotate z*352*clock
    look_at<0,0,0>
    }
//camera{ location <-1,0,-6> look_at<0,0,0> }

#declare myroundrect =
merge {
    box{ <-1,-3,0 >, <1,-2,0.2> }
    box{ <-1,2,0 >, <1,3,0.2> }
    box{ <-3,-1,0 >, <-2,1,0.2> }
    box{ <2,-1,0 >, <3,1,0.2> }
    cylinder{ <-1,-1,0>, <-1,-1,0.2>, 2 }
    cylinder{ <1,-1,0>, <1,-1,0.2>, 2 }
    cylinder{ <-1,1,0>, <-1,1,0.2>, 2 }
    cylinder{ <1,1,0>, <1,1,0.2>, 2 }
}
#declare threecyl =
merge{
    cylinder{ <1,1.5,0>, <1,1.5,-0.01>, 0.9 }
    cylinder{ <-1.5,0,0>, <-1.5,0,-0.01>, 0.9 }
    difference{
	    cylinder{ <1,-1.5,0>, <1,-1.5,-0.01>, 0.9 }
            cylinder{ <1,-1.5,0.1>, <1,-1.5,-0.02>, 0.7 }
            }
    box{ <-1.5,-0.1,0 >, <1.5,0.1,0.01> 
        rotate 35*z
        translate z*-0.01
        translate y*0.9
    }
    box{ <-1.5,-0.1,0 >, <0.3,0.1,0.01> 
        rotate -35*z
        translate z*-0.01
        translate y*-0.9
    }
}

object {
    difference{
        object { myroundrect scale 1 }
        object { myroundrect scale 0.94 translate z*-0.10 }
        object { myroundrect scale 0.96 translate z*-0.13 }
        object { myroundrect scale 0.98 translate z*-0.16 }
        }
    texture {
        pigment { rgb <0.3,0.8,0.3> }
        finish { Metallic_Finish }
        }
    }

object {
    threecyl
    translate z*.07
    pigment { color White }
    }
#declare pos1=<1,1.5,0>;
#declare pos2=<-1.5,0,0>;
#declare pos3=<1,-1.5,0>;
#declare cyl= cylinder{
	<0.5,0.5,0>, <0.5,0.5,0.1>, 0.5
	pigment{ image_map { png "grumpy_cat2.png" map_type 0 } }
        translate <-0.5,-0.5,0>
        rotate z*352*clock
	}

#declare frac=1/12;
#switch(clock)
    #range(frac*0,frac*1)
    object { cyl translate pos1 + <-2.5,-1.5,0>*clock*1/frac }
    #break
    #range(frac*1,frac*2)
    object { cyl translate pos2 + <2.5,-1.5,0>*(clock-1*frac)*1/frac }
    #break
    #range(frac*2,frac*3)
    object { cyl translate pos3 + <-2.5,1.5,0>*(clock-2*frac)*1/frac }
    #break
    #range(frac*3,frac*4)
    object { cyl translate pos2 + <2.5,1.5,0>*(clock-3*frac)*1/frac }
    #break
    #range(frac*4,frac*5)
    object { cyl translate pos1 + <-2.5,-1.5,0>*(clock-4*frac)*1/frac }
    #break
    #range(frac*5,frac*6)
    object { cyl translate pos2 + <2.5,-1.5,0>*(clock-5*frac)*1/frac }
    #break
    #range(frac*6,frac*7)
    object { cyl translate pos3 + <-2.5,1.5,0>*(clock-6*frac)*1/frac }
    #break
    #range(frac*7,frac*8)
    object { cyl translate pos2 + <2.5,1.5,0>*(clock-7*frac)*1/frac }
    #break
    #range(frac*8,frac*9)
    object { cyl translate pos1 + <-2.5,-1.5,0>*(clock-8*frac)*1/frac }
    #break
    #range(frac*9,frac*10)
    object { cyl translate pos2 + <2.5,-1.5,0>*(clock-9*frac)*1/frac }
    #break
    #range(frac*10,frac*11)
    object { cyl translate pos3 + <-2.5,1.5,0>*(clock-10*frac)*1/frac }
    #break
    #range(frac*11,1.0)
    object { cyl translate pos2 + <2.5,1.5,0>*(clock-11*frac)*1/frac }
    #break
#end

plane { z,0.12 pigment { color White } }